Nodes:0#`
Lines:2#,!0
Circles:2#,0#0.

circles:{							/ generate circles
 if[0<#Nodes
  c:_(#Nodes)%r:__sqrt#Nodes;r+:(#Nodes)!r
  Circles::+,/(1+(!r),\:/:!c)*\:\:(x,y)%1+r,c]
}

load:{t:1:x;;@[_d;!t;:;t[]];}					/ load file
save:{x 1:.+(`Nodes`Circles`Lines;(Nodes;Circles;Lines))}	/ object

cc:{[d;c;r]_sqr[r*2]>+/_sqr d-c}				/ circles overlap?
pc:{[p;c;r]_sqr[r]>+/_sqr p-c}					/ point in circle?
dpp:{[p;q]_sqrt+/_sqr p-q}					/ dist point to point
dpc:{[p;c;r]dpp[p;c]-r}						/ dist point to circle
dpl:{[p;s;e]dpp[p]ip[p;s;e]}					/ dist point to line
nc:{e?&/e:dpc[x,y;Circles]z}					/ nearest circle to point
nl:{d?&/d:dpl[x,y].'+(+Circles)Lines} 				/ nearest line to point
sl:%/|-            						/ slope of line

sel:{x!#*Circles}						/ next select		

ip:{[p;s;e]							/ point on line
 if[s[0]=*e;:s[0],p 1]
 if[s[1]=e 1;:p[0],s 1]
 i:-%k:sl[e]s
 x:(p[1]+(k**s)-s[1]+i**p)%k-i
 y:s[1]+k*x-*s
 x,y}

icr:{[c;p;r]							/ point on circle w/radius
 if[c[0]=*p;:c[0],:[c[1]>p 1;c[1]-r;r+c 1]]
 if[c[1]=p 1;::[c[0]>*p;c[0]-r;r+*c],c 1]
 t:r%_sqrt 1+_sqr m:sl[p]c
 x1:c[0]+t;y1:c[1]+m*x1-*c;p1:x1,y1
 x2:c[0]-t;y2:c[1]+m*x2-*c;p2:x2,y2
 :[dpp[p1;p]<dpp[p2]p;p1;p2]}

overlaps:{[x;y;r]|/cc[x,y;Circles]r}
collides:{[x;y;r;i]|/cc[x,y;Circles _di\:i]r}
appendcircle:{Circles[],:x,y;Nodes,:z;-1+#*Circles}
circle:{Circles[;x]}
line:{+Circles[;Lines[;x]]}
node:{Circles[;nc[x;y]z]}
to:{[x;y;z;w;r]chk[of x,y;nc[z;w]r]1}
from:{[x;y;z;w;r]chk[of z,w;nc[x;y]r]0}
chk:{:[x=y;,();exists[x]y;();loop[x;y]z;();Circles[;y]]}
loop:{:[x _in y,:();1;y~c:?y,Lines[z;&Lines[~z]_lin y];0;_f[x;c]z]}
exists:{|/&/Lines=x,y}
of:{*&&/Circles=x}
appendline:{[x;y;z;w]Lines[],:of'(x,y;z,w)}
nearest:{(i;Circles[;i:nc[x;y]z])}
lines:{+Circles[;Lines[~y;&x=Lines y]]}
setcircle:{[i;x;y]Circles[;i]:x,y}
setline:{[i;x;y;z;w]Lines[;i]:of'(x,y;z,w)}
deleteline:{[i]Lines::Lines _di\:i}
symbol:{:[x _in Nodes;0;~*.[@;_n,x;:]]}
S:-1;nextsymbol:{`$"node",$S+:1}
point:{[x;y;z;w;r]icr[z,w;x,y]r}

arrow:{[x;y;z;w;r]
 a:point[z;w;x;y]r
 b:point[x;y;z;w]r*1.5
 c:point[x;y;;;r*.5]. b
 (a;c;b;r*.5)}

end:{
 i:nl[x]y
 f:Circles[;Lines[0;i]]
 t:Circles[;Lines[1;i]]
 (i;dpp[x,y;f]<dpp[x,y]t;f;t)}

deletecircle:{
 r:(Circles[;x];+(+Circles)Lines[;i:&|/Lines=x])
 Circles::Circles _di\:x
 Nodes::Nodes _di x
 Lines::Lines _di\:i
 Lines::Lines-Lines>x
 r}