[a-]                            pop
[ab-ba]                         swap
[a-aa]                          dup

[[[[a A]]a A]`]                 uncons
[[[a b][a]b,]`!]                cons

"combinators"

[[[a b][b!a]]`!]                dip
[[unit!]dip!:popd!]             right
[swapd![swap!]swap!,right!]     left

"operators"

[[]!]                           id
[uncons!pop!]                   first
[uncons![pop!]dip!]             rest
[|first!]                       last
[''dip!]                        unit
[unit!cons!]                    pair
[uncons!first!]                 unpair
[swapd!swap!]                   bot             "rot"
[swap!swapd!]                   top             "-rot"
[[pop!]dip!]                    popd
[[dup!]dip!]                    dupd
[[cons!]dip!]                   consd
[[swap!]dip!]                   swapd
['dip!cons!dip!]                dipd
[swap!cons!]                    swons
[1+]                            succ
[-1+]                           pred
[-1*]                           neg
[0 swap!(first!]                proto
[unit!pair!.]                   of              "x y"

"predicates"

[#ints~]                        atom            "@x"
[atom!not!]                     list            "~@x"
[count!0=]                      empty           "~#x"
[0~]                            false           "0~x"

"monads"

[0=]                            not             "~x"
[#first!]                       count           "#x"
[1swap!%]                       recip           "%x"
[<|]                            down            ">x"

"dyads"

[swap!>]                        less            "x<y"
[not![not!]dip!&not!]           or              "x|y"
[neg![neg!]dip!&neg!]           max             "x|y"

"continuations"

[[[pop![]]dip!]$]                       clearstack
[[pop![]]$]                             clearqueue
[[][]$]                                 clear

[[[|uncons!|swap!]dip!swap!unit!,]$]    queue
[[|uncons!|[unit!,]dip!]$]              unqueue

[[[dup!unit!,]dip!]$]                   stack
[[[last!]dip!]$]                        unstack

"controls"

[pair![dupd!]dip!'!dip!swap!false!pair!.!]              cond            "[c][t][f]cond!"
[[]cond!]                                               if              "[c][t]if!"
[unit!cons!dup![uncons!uncons!pop!]dip![while!],,if!]   while           "[c][t]while!"
[unit![pred!]swap!,'dip!,[]swap!while!pop!]             do              "n[f]do!"

"adverbs"

[[dup!proto!swap!unit!]dip!/]           reduce          "[..][f2]reduce!"
[[dup!proto!swap!unit!]dip!\)]          scan            "[..][f2]scan!"

['+reduce!]                             sum             "[..]sum!"
['+scan!]                               cum             "[..]cum!"

[[unit!]dip!/]                          fold            "s[..][f2]fold!"

[[unit!]dip!:]                          true            "[..][b]true!"
[true!1 swap!'&fold!]                   all             "[..][b]all!"
[true!0 swap![or!]fold!]                some            "[..][b]some!"

[[dup!count![]top!]dip!swap!
 [[uncons!]dip!dup!top!
  [cons!unit!. first!swons!]dipd!]
 do!pop!pop!|]                          map             "[..][f]map!"

[[pair!@]dip!'!swap!,map!]              both            "[..][..][f]both!"

[[dup!]dip!swap![map!]dip!swap!@of!]    filter          "[..][f]filter!"

[stack![filter!]dip!
 |uncons!
 [[not!],]dip!cons!|
 [filter!],unit!. last!swap!]           split           "[..][f]split!"